Wifi 연결 유지하기(윈도우)-Batch 반복

 개요

이전에 작성한  Wifi 연결 유지 방식은 배치파일을 작업 배치를 통해 연겨랗는거라 설정하기가 조금 번거로울 수 있습니다.
배치파일 자체로 반복(10분 주기)하여 실행하여 간단히 실행 할 수 있도록 변경하였습니다.

2021.02.09 - [OS/Windows] - WiFi 연결 유지하기(윈도우)

WiFi 연결 유지하기(윈도우)

 배치파일

아래 배치파일을 다운 받으세요.

wifi_reconn.bat

0.00MB

아니면 아래 코드를 가져가서 배치파일로 만들어서 사용하셔도 됩니다.

@echo off

@set CHECK_SSID=wifi_XXX
echo SSID : %CHECK_SSID% 연결을 확인합니다.

:start

@set YEAR=%date:~0,4%
@set MONTH=%date:~5,2%
@set DAY=%date:~8,2%
@set HOUR=%time:~0,2%
@set MINUTE=%time:~3,2%
@set SECOND=%time:~6,2%
@set POSTFIX=%YEAR%-%MONTH%-%DAY%_%HOUR%-%MINUTE%-%SECOND%

rem echo %POSTFIX%_start >> log.out

for /f "tokens=3" %%i in ('netsh wlan show interface ^| findstr /i "SSID"') do set "myssid=%%i" & goto next
:next
set "myssid=%myssid: =%"
echo myssid : %myssid%

if /i "%myssid%"=="%CHECK_SSID%" (
   echo "Status Good"
   rem echo %POSTFIX%_good >> log.out
 ) ELSE (
   echo "Reconnect"
   netsh wlan connect name="%CHECK_SSID%"
   rem echo %POSTFIX%_reconnect >> log.out
)

rem echo %POSTFIX%_end >> log.out

set myssid=""

timeout /t 600

goto start

실행 결과를 파일로 보고 싶으시면 rem으로 주석된 부분을 rem을 제거하여 사용하면 배치파일과 같은 폴더에 log.out 파일이 생성되며 로그가 누적되어 저장됩니다.

배치 실행 화면

600초, 10분 마다 Wifi 연결 상태를 확인하고 연결이 안되어 있을 경우 재연결합니다.
시간을 변경하실 때는 "timeout /t 초" 여기에 원하시는 대기시간을 수정하여 사용하면 됩니다.