크롬 인증서 오류 무시

 개요

특정 사이트를 접속 시 인증서 문제로 접속이 되지 않는 경우가 있다.
크롬 사용 시  --ignore-certificate-errors -test-type  옵션을 chrome.lnk 파일의 대상에 추가하면 인증서 오류를 문시하고 사용할 수 있다.

크롬 인증서 오류 무시

 윈도우 작업 표시줄의 크롬 실행 시 미적용 문제

윈도우 작업표시줄의 크롬 아이콘을 통해 실행하게 되면 인증서 무시 옵션이 적용되지 않는다.

 해결방안

윈도우 시작버튼 > Chrome > 자세히 > 파일 위치 열기

C:\ProgramData\Microsoft\Windows\Start Menu\Programs 이 폴더로 이동하게 된다.

여기에 있는 Chrome.lnk 파일도 속성을 눌러 대상에 
--ignore-certificate-errors -test-type 를 추가한다.

 크롬 인증서 무시 링크 생성 배치

아래 내용을 배치 파일로 만들어 실행하게 되면 관리자 권한을 얻어 바탕화면과 스타트메뉴에 크롬링크를 생성한다.

@echo off

echo =========================== Got Admin Grant ===========================

rem batch run directory
set batpath=%~dp0
echo %batpath%

echo got Admin 

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
  echo Run as Administrator...
  goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
  echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
  set params = %*:"=""
  echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"
  "%temp%\getadmin.vbs"
  del "%temp%\getadmin.vbs"
  exit /B
:gotAdmin

rem set lnk=%userprofile%\desktop\Chrome.lnk
set lnk=%batpath%\Chrome.lnk
set tgpath="C:\Program Files\Google\Chrome\Application\chrome.exe"
set "arg= --ignore-certificate-errors -test-type"
set icon=
set startLocation="C:\Program Files\Google\Chrome\Application"

set command=^
$objshell = New-object -ComObject WScript.Shell;^
$lnk = $objshell.CreateShortcut('%lnk%');^
$lnk.TargetPath='%tgpath%';^
$lnk.WorkingDirectory='%startLocation%';^
$lnk.Arguments='%arg%';

if not "%icon%"=="" set command=%command%$lnk.IconLocation ^='%icon%';
set command=%command%$lnk.Save();

powershell -command "& {%command%}"


rem command line move to batch directory

%~d0
cd %~dp0

rem copy to desktop
set commonpath="C:\Users\Public\Desktop"

if exist %commonpath% (
  	echo "Common Chrome Exist"
	copy /y %batpath%\Chrome.lnk %commonpath%\
) else (
	echo "Common Chrome Not Exist"
	copy /y %batpath%\Chrome.lnk %userprofile%\desktop\
)

rem copy to start menu
copy /y %batpath%\Chrome.lnk "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\"


pause

아래 배치 파일 첨부함

makeLinkChromeAndStartMenu.bat

0.00MB